Open Source Snapmatic picture and Savegame viewer/editor for GTA V https://gta5view.syping.de/

gta5view.pro 7.1KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254
  1. #/*****************************************************************************
  2. #* gta5view Grand Theft Auto V Profile Viewer
  3. #* Copyright (C) 2015-2018 Syping
  4. #*
  5. #* This program is free software: you can redistribute it and/or modify
  6. #* it under the terms of the GNU General Public License as published by
  7. #* the Free Software Foundation, either version 3 of the License, or
  8. #* (at your option) any later version.
  9. #*
  10. #* This program is distributed in the hope that it will be useful,
  11. #* but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. #* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. #* GNU General Public License for more details.
  14. #*
  15. #* You should have received a copy of the GNU General Public License
  16. #* along with this program. If not, see <http://www.gnu.org/licenses/>.
  17. #*****************************************************************************/
  18. QT += core gui network
  19. greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
  20. greaterThan(QT_MAJOR_VERSION, 4): greaterThan(QT_MINOR_VERSION, 1): win32: QT += winextras
  21. DEPLOYMENT.display_name = gta5view
  22. TARGET = gta5view
  23. TEMPLATE = app
  24. HEADERS += config.h
  25. PRECOMPILED_HEADER += config.h
  26. SOURCES += main.cpp \
  27. AboutDialog.cpp \
  28. AppEnv.cpp \
  29. CrewDatabase.cpp \
  30. DatabaseThread.cpp \
  31. ExportDialog.cpp \
  32. ExportThread.cpp \
  33. GlobalString.cpp \
  34. IconLoader.cpp \
  35. ImageEditorDialog.cpp \
  36. ImportDialog.cpp \
  37. JsonEditorDialog.cpp \
  38. MapLocationDialog.cpp \
  39. OptionsDialog.cpp \
  40. PictureDialog.cpp \
  41. PictureExport.cpp \
  42. PictureWidget.cpp \
  43. PlayerListDialog.cpp \
  44. ProfileDatabase.cpp \
  45. ProfileInterface.cpp \
  46. ProfileLoader.cpp \
  47. ProfileWidget.cpp \
  48. SavegameCopy.cpp \
  49. SavegameData.cpp \
  50. SavegameDialog.cpp \
  51. SavegameWidget.cpp \
  52. SidebarGenerator.cpp \
  53. SnapmaticEditor.cpp \
  54. SnapmaticPicture.cpp \
  55. SnapmaticWidget.cpp \
  56. StandardPaths.cpp \
  57. StringParser.cpp \
  58. TelemetryClass.cpp \
  59. TranslationClass.cpp \
  60. UserInterface.cpp \
  61. anpro/imagecropper.cpp \
  62. dnr/DonationDialog.cpp \
  63. pcg/pcg_basic.c \
  64. tmext/TelemetryClassAuthenticator.cpp \
  65. uimod/JSHighlighter.cpp \
  66. uimod/UiModLabel.cpp \
  67. uimod/UiModWidget.cpp
  68. HEADERS += \
  69. AboutDialog.h \
  70. AppEnv.h \
  71. CrewDatabase.h \
  72. DatabaseThread.h \
  73. ExportDialog.h \
  74. ExportThread.h \
  75. GlobalString.h \
  76. IconLoader.h \
  77. ImageEditorDialog.h \
  78. ImportDialog.h \
  79. JsonEditorDialog.h \
  80. MapLocationDialog.h \
  81. OptionsDialog.h \
  82. PictureDialog.h \
  83. PictureExport.h \
  84. PictureWidget.h \
  85. PlayerListDialog.h \
  86. ProfileDatabase.h \
  87. ProfileInterface.h \
  88. ProfileLoader.h \
  89. ProfileWidget.h \
  90. SavegameCopy.h \
  91. SavegameData.h \
  92. SavegameDialog.h \
  93. SavegameWidget.h \
  94. SidebarGenerator.h \
  95. SnapmaticEditor.h \
  96. SnapmaticPicture.h \
  97. SnapmaticWidget.h \
  98. StandardPaths.h \
  99. StringParser.h \
  100. TelemetryClass.h \
  101. TranslationClass.h \
  102. UserInterface.h \
  103. anpro/imagecropper.h \
  104. anpro/imagecropper_e.h \
  105. anpro/imagecropper_p.h \
  106. dnr/DonationDialog.h \
  107. pcg/pcg_basic.h \
  108. tmext/TelemetryClassAuthenticator.h \
  109. uimod/JSHighlighter.h \
  110. uimod/UiModLabel.h \
  111. uimod/UiModWidget.h
  112. FORMS += \
  113. AboutDialog.ui \
  114. ExportDialog.ui \
  115. ImageEditorDialog.ui \
  116. ImportDialog.ui \
  117. JsonEditorDialog.ui \
  118. MapLocationDialog.ui \
  119. OptionsDialog.ui \
  120. PictureDialog.ui \
  121. PlayerListDialog.ui \
  122. ProfileInterface.ui \
  123. SavegameDialog.ui \
  124. SavegameWidget.ui \
  125. SnapmaticEditor.ui \
  126. SnapmaticWidget.ui \
  127. UserInterface.ui
  128. TRANSLATIONS += \
  129. res/gta5sync.ts \
  130. res/gta5sync_de.ts \
  131. res/gta5sync_en_US.ts \
  132. res/gta5sync_es.ts \
  133. res/gta5sync_fr.ts \
  134. res/gta5sync_ru.ts \
  135. res/gta5sync_uk.ts \
  136. res/gta5sync_zh_TW.ts
  137. RESOURCES += \
  138. res/tr_g5p.qrc \
  139. res/app.qrc
  140. DISTFILES += res/app.rc \
  141. res/gta5view.desktop \
  142. res/gta5sync_de.ts \
  143. res/gta5sync_en_US.ts \
  144. res/gta5sync_es.ts \
  145. res/gta5sync_fr.ts \
  146. res/gta5sync_ru.ts \
  147. res/gta5sync_uk.ts \
  148. res/gta5sync_zh_TW.ts \
  149. res/gta5view.exe.manifest \
  150. res/gta5view.png \
  151. lang/README.txt
  152. INCLUDEPATH += ./anpro ./dnr ./pcg ./tmext ./uimod
  153. # GTA5SYNC/GTA5VIEW ONLY
  154. DEFINES += GTA5SYNC_PROJECT # Enable exclusive gta5sync/gta5view functions
  155. DEFINES += GTA5SYNC_NOASSIST # Not assisting at proper usage of SnapmaticPicture class
  156. # WINDOWS ONLY
  157. win32: DEFINES += GTA5SYNC_WIN
  158. win32: RC_FILE += res/app.rc
  159. win32: LIBS += -luser32
  160. win32: CONFIG -= embed_manifest_exe
  161. contains(DEFINES, GTA5SYNC_APV): greaterThan(QT_MAJOR_VERSION, 4): greaterThan(QT_MINOR_VERSION, 1): win32: LIBS += -ldwmapi
  162. contains(DEFINES, GTA5SYNC_TELEMETRY): win32: LIBS += -ld3d9 # Required for getting information about GPU
  163. # MAC OS X ONLY
  164. macx: ICON = res/5sync.icns
  165. # QT4 ONLY STUFF
  166. isEqual(QT_MAJOR_VERSION, 4): INCLUDEPATH += ./qjson4
  167. isEqual(QT_MAJOR_VERSION, 4): HEADERS += qjson4/QJsonArray.h \
  168. qjson4/QJsonDocument.h \
  169. qjson4/QJsonObject.h \
  170. qjson4/QJsonParseError.h \
  171. qjson4/QJsonValue.h \
  172. qjson4/QJsonValueRef.h \
  173. qjson4/QJsonParser.h \
  174. qjson4/QJsonRoot.h
  175. isEqual(QT_MAJOR_VERSION, 4): SOURCES += qjson4/QJsonArray.cpp \
  176. qjson4/QJsonDocument.cpp \
  177. qjson4/QJsonObject.cpp \
  178. qjson4/QJsonParseError.cpp \
  179. qjson4/QJsonValue.cpp \
  180. qjson4/QJsonValueRef.cpp \
  181. qjson4/QJsonParser.cpp
  182. isEqual(QT_MAJOR_VERSION, 4): RESOURCES += res/tr_qt4.qrc
  183. isEqual(QT_MAJOR_VERSION, 4): GTA5SYNC_RCC = $$[QT_INSTALL_BINS]/rcc
  184. # QT5 ONLY STUFF
  185. isEqual(QT_MAJOR_VERSION, 5): RESOURCES += res/tr_qt5.qrc
  186. isEqual(QT_MAJOR_VERSION, 5): GTA5SYNC_RCC = $$[QT_HOST_BINS]/rcc
  187. # RESOURCE COMPILATION
  188. depend.depends += $$PWD/res/global.qrc
  189. depend.commands += $$GTA5SYNC_RCC -binary -threshold 0 -compress 9 $$PWD/res/global.qrc -o $$PWD/res/global.rcc
  190. QMAKE_EXTRA_TARGETS += depend
  191. # PROJECT INSTALLATION
  192. isEmpty(GTA5SYNC_PREFIX): GTA5SYNC_PREFIX = /usr/local
  193. appfiles.path = $$GTA5SYNC_PREFIX/share/applications
  194. appfiles.files = $$PWD/res/gta5view.desktop
  195. pixmaps.path = $$GTA5SYNC_PREFIX/share/pixmaps
  196. pixmaps.files = $$PWD/res/gta5view.png
  197. target.path = $$GTA5SYNC_PREFIX/bin
  198. INSTALLS += target pixmaps appfiles
  199. # QCONF BASED BUILD STUFF
  200. contains(DEFINES, GTA5SYNC_QCONF){
  201. isEqual(QT_MAJOR_VERSION, 4): RESOURCES -= res/tr_qt4.qrc
  202. isEqual(QT_MAJOR_VERSION, 5): RESOURCES -= res/tr_qt5.qrc
  203. !contains(DEFINES, GTA5SYNC_QCONF_IN){
  204. RESOURCES -= res/tr_g5p.qrc
  205. langfiles.path = $$GTA5SYNC_PREFIX/share/gta5view/translations
  206. langfiles.files = $$PWD/res/gta5sync_en_US.qm $$PWD/res/gta5sync_de.qm $$PWD/res/gta5sync_fr.qm $$PWD/res/gta5sync_ru.qm $$PWD/res/gta5sync_uk.qm $$PWD/res/gta5sync_zh_TW.qm $$PWD/res/qtbase_en_GB.qm $$PWD/res/qtbase_zh_TW.qm
  207. INSTALLS += langfiles
  208. }
  209. }
  210. # DONATION BASED STUFF
  211. !contains(DEFINES, GTA5SYNC_DONATION){
  212. SOURCES -= dnr/DonationDialog.cpp
  213. HEADERS -= dnr/DonationDialog.h
  214. }
  215. # TELEMETRY BASED STUFF
  216. !contains(DEFINES, GTA5SYNC_TELEMETRY){
  217. SOURCES -= TelemetryClass.cpp \
  218. tmext/TelemetryClassAuthenticator.cpp
  219. HEADERS -= TelemetryClass.h \
  220. tmext/TelemetryClassAuthenticator.h
  221. }